nixos-config/hosts/x86_64-linux/lenny/default.nix

{ pkgs, ... }:
{
  services = {
    openssh.enable = true;
  };

  users.mutableUsers = false;
  users.users.root.passwordFile = "/nix/persist/shadow_sean";
  users.users.sean.passwordFile = "/nix/persist/shadow_sean";

  environment.etc =
    builtins.listToAttrs (map
      (name: { inherit name; value.source = "/nix/persist/etc/${name}"; })
      [
        "machine-id"
        "NetworkManager/system-connections"
        "ssh/ssh_host_ed25519_key"
        "ssh/ssh_host_rsa_key"
      ]);

  sconfig = {
    gnome = true;
    profile = "desktop";
    hardware = "physical";
  };

  environment.systemPackages = [ pkgs.vmware-horizon-client ];

  boot = {
    loader.systemd-boot.enable = true;
    loader.efi.canTouchEfiVariables = true;
  };

  fileSystems = {
    "/" = { device = "tmpfs"; fsType = "tmpfs"; options = [ "mode=755" ]; };
    "/nix" = { device = "lenny/locker/nix"; fsType = "zfs"; };
    "/home" = { device = "lenny/locker/home"; fsType = "zfs"; };
    "/boot" = { device = "/dev/disk/by-partlabel/_esp"; fsType = "vfat"; };
  }
  // builtins.listToAttrs (map
    (name: { inherit name; value = { device = "/nix/persist${name}"; noCheck = true; options = [ "bind" ]; }; })
    [ "/var/log" ]);

  system.stateVersion = "21.11";
}