From 598579db379a4f5a1c8e32d661a2042927b607eb Mon Sep 17 00:00:00 2001
From: Sean Buckley <sean.bck@gmail.com>
Date: Thu, 18 Nov 2021 00:17:43 -0500
Subject: [PATCH] wordlists: init

---
 pkgs/default.nix                  |  3 +-
 pkgs/security-toolbox/default.nix |  2 ++
 pkgs/wordlists.nix                | 56 +++++++++++++++++++++++++++++++
 3 files changed, 60 insertions(+), 1 deletion(-)
 create mode 100644 pkgs/wordlists.nix

diff --git a/pkgs/default.nix b/pkgs/default.nix
index c0dd8a4..6d70d4b 100644
--- a/pkgs/default.nix
+++ b/pkgs/default.nix
@@ -13,7 +13,8 @@ rec
   commander-x16 = pkg ./commander-x16 { };
   gef = pkg ./gef { };
   msfpc = pkg ./msfpc { };
-  security-toolbox = pkg ./security-toolbox { inherit gef msfpc webshells weevely; };
+  security-toolbox = pkg ./security-toolbox { inherit gef msfpc webshells weevely security-wordlists; };
+  security-wordlists = pkg ./wordlists.nix { };
   SpaceCadetPinball = pkg ./SpaceCadetPinball { };
   stretchy-spaces = pkg ./stretchy-spaces { };
   webshells = pkg ./webshells { };
diff --git a/pkgs/security-toolbox/default.nix b/pkgs/security-toolbox/default.nix
index eef0068..f90ba89 100644
--- a/pkgs/security-toolbox/default.nix
+++ b/pkgs/security-toolbox/default.nix
@@ -18,6 +18,7 @@
 , nmap
 , openvpn
 , remmina
+, security-wordlists
 , socat
 , thc-hydra
 , webshells
@@ -70,6 +71,7 @@ symlinkJoin {
       nmap
       openvpn
       remmina
+      security-wordlists
       socat
       thc-hydra
       webshells
diff --git a/pkgs/wordlists.nix b/pkgs/wordlists.nix
new file mode 100644
index 0000000..a67ce26
--- /dev/null
+++ b/pkgs/wordlists.nix
@@ -0,0 +1,56 @@
+{ lib
+, fetchFromGitHub
+, fetchFromGitLab
+, nmap
+, runCommand
+, wfuzz
+}:
+let
+
+  nmap-data = runCommand "nmap-data" { } ''
+    tar --strip-components=1 -xvf ${nmap.src}
+    mv nselib/data $out
+  '';
+
+  seclists = fetchFromGitHub {
+    owner = "danielmiessler";
+    repo = "SecLists";
+    rev = "cb81804316c634728bbddb857ce7dfa5016e01b1";
+    sha256 = "QBlZlS8JJI6pIdIaD1I+7gMuPPfEybxybj2HrnQM7co=";
+  };
+
+  rockyou = runCommand
+    "rockyou.txt"
+    {
+      src = fetchFromGitLab {
+        group = "kalilinux";
+        owner = "packages";
+        repo = "wordlists";
+        rev = "upstream/0.3";
+        sha256 = "1slsz9mzcbvfvx928drvf9ayq3q5wbfqgm0p1khxc7m9yf20ilm2";
+      };
+    }
+    "gunzip <$src/rockyou.txt.gz >$out";
+
+  dirbuster = runCommand
+    "dirbuster"
+    {
+      src = fetchFromGitLab {
+        group = "kalilinux";
+        owner = "packages";
+        repo = "dirbuster";
+        rev = "upstream/1.0";
+        sha256 = "1500imrwhwr1zl59z1hq2bqhn05xjjl9lf3vp7dyx7dfx517i43y";
+      };
+    }
+    "mkdir -p $out; cp -v $src/*.txt $out/";
+
+in
+runCommand "wordlists" { } ''
+  mkdir -p $out/share/wordlists
+  ln -s ${wfuzz.src}/wordlist $out/share/wordlists/wfuzz
+  ln -s ${nmap-data} $out/share/wordlists/nmap
+  ln -s ${seclists} $out/share/wordlists/seclists
+  ln -s ${rockyou} $out/share/wordlists/rockyou.txt
+  ln -s ${dirbuster} $out/share/wordlists/dirbuster
+''